How to use only <title>Title text</title> as title (when many title marks exist)

<xsl:template name="get-title">
      <xsl:value-of select="//title" />
  </xsl:template>

Yeah, that should only get the <title> element.

There is some fallback code that tries for other options, but it's supposed to only try that if the early lookups fail.

The code in the generic html2simplehtml.xsl template does this

  <xsl:template name="get-title">
    <!-- 
      Note: TODO 
      Need to deal with the possible difference between 
      document title and H1 display title .
      Look for H1 or anything id=pagetitle first
      If that fails, use the meta title.
      Some exceptions to do so are defined later.
      
      Sometimes need to remove the header from the body once i've found it?
    -->
      <xsl:choose>
  
        <xsl:when test="descendant::*[local-name()='h1']">
            <xsl:value-of select="normalize-space(descendant::*[local-name()='h1'])" />
        </xsl:when>
        
        <xsl:when test="//*[@id='pagetitle']">
          <!-- 
            Nice sites set the id of their title.
            May add other #ids here as I find them
          -->
            <xsl:value-of select="normalize-space(descendant::*[@id='pagetitle'])" />
        </xsl:when>

        <xsl:when test="count(descendant::h2|descendant::xhtml:h2)=1">
          <!-- 
            Maybe it used an h2 because h1 was ugly.
            If there is ONLY ONE h2, use that
          -->
            <xsl:value-of select="normalize-space(descendant::h2|descendant::xhtml:h2)" />
        </xsl:when>
        
        <xsl:otherwise>
          <!-- 
            In practice, the html head title is often more verbose than we want
            and too often it's the same across whole sections, but it'll have to do.
          -->
            <xsl:value-of select="normalize-space(descendant::*[name() = 'title'])" />
        </xsl:otherwise>
        <!--
          Any of these steps may fail if the heading contains only html, eg
          <h1><img src='header.gif' /></h1>
        -->
      </xsl:choose>
  </xsl:template>

the "choose/when" means only one match will match.

Your version would also work, and is the expected way you would get what you want (as long as namespaces don't get in the way)

Attach your XSL and source doc and it may reveal what's going wrong

The example starter is easier to look at.
H1 or TITLE, in that order

  <xsl:template name="get-title">
    <!-- 
    Returns the H1, or if unavailable, the <title>
    -->
    <xsl:choose>
      <xsl:when test="//xhtml:h1">
        <xsl:value-of select="normalize-space(//xhtml:h1)" />
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="normalize-space(//xhtml:title)" />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>